Games Central GT Digital… Q3 Premier Trimestre '98/GT_DPK.ISO/pc/data/menu.dxr/00062_Image Switch Cast Members.ls

Text File | 1995-08-25 | 3.7 KB | 85 lines

property name, setting, Memberalt, MemberOne, GroupName, MemberAltName

on SetState me, state, Addressee
  if voidp(Addressee) then
    do_SetState(me, state)
  else
    case Addressee of
      #all:
        do_SetState(me, state)
      (the name of me):
        do_SetState(me, state)
      (the GroupName of me):
        do_SetState(me, state)
    end case
  end if
end

on SwitchStates me, Addressee
  if voidp(Addressee) then
    do_SwitchStates(me)
  else
    case Addressee of
      #all:
        do_SwitchStates(me)
      (the name of me):
        do_SwitchStates(me)
      (the GroupName of me):
        do_SwitchStates(me)
    end case
  end if
end

on do_SetState me, state
  set the setting of me to state
  if state = 1 then
    set the member of sprite the spriteNum of me to the MemberOne of me
  else
    set the member of sprite the spriteNum of me to the Memberalt of me
  end if
end

on do_SwitchStates me
  if the setting of me = 1 then
    set the setting of me to 2
    set the member of sprite the spriteNum of me to the Memberalt of me
  else
    if the setting of me = 2 then
      set the setting of me to 1
      set the member of sprite the spriteNum of me to the MemberOne of me
    end if
  end if
  return the setting of me
end

on beginSprite me
  set the MemberOne of me to the member of sprite the spriteNum of me
  set the Memberalt of me to member the MemberAltName of me
  if setting = 1 then
    do_SetState(me, 2)
  else
    do_SetState(me, 1)
  end if
end

on getPropertyDescriptionList
  if the currentSpriteNum = 0 then
    set memdefault to 0
  else
    set memref to the member of sprite the currentSpriteNum
    set castLibNum to the castLibNum of memref
    set memdefault to member (the memberNum of member memref + 1) of castLib castLibNum
  end if
  set p_list to [#name: [#comment: "Item Name:", #format: #symbol, #default: #twostate1], #MemberAltName: [#comment: "Alternate Image Name:", #format: #graphic, #default: memdefault], #setting: [#comment: "Initially Toggled:", #format: #boolean, #default: 0], #GroupName: [#comment: "Group Name:", #format: #symbol, #default: #group1]]
  return p_list
end

on getBehaviorDescription
  return "Switches cast members when the SwitchStates message is received. Switches to a particular state when the SetState message is received. Enter a Group Name to include the current sprite in a group of sprites that respond to the same message. " & RETURN & "PARAMETERS:" & RETURN & "ΓÇó Item Name - (optional) Enter an item name to identify the current sprite so that it can receive a specific message. Do not use spaces. Use the name as an argument for the Message Sprite or Message All Sprites behaviors." & RETURN & "ΓÇó Alternate Image - number of castmember whose image will replace normal image.  Must be stored in same cast library as Normal castmember." & RETURN & "ΓÇó Initially Toggled - Turn this option on if sprite's current cast member represents the alternate rather than the normal state of the sprite." & RETURN & "ΓÇó Group Name - (optional) Enter a Group Name to include the current sprite in a group of sprites that respond to the same message. Do not use spaces. Use the name as an argument for the Message Sprite or Message All Sprites behaviors." & RETURN & "MESSAGES:" & RETURN & "ΓÇó SwitchStates [ID] - Switches the sprite's cast member. ID is the Item Name or Group Name of the sprite. Returns the current state of the sprite, 0 (normal) or 1 (alternate)." & RETURN & "ΓÇó SetState {0 or 1}, [ID] - Sets the sprite to state 0 (normal) or 1 (alternate). ID is the Item Name or Group Name of the sprite. If the ID is omitted any sprite receiving the message will SetState."
end

on getAssocMembers
  set myPropList to [MemberAltName]
  return myPropList
end